[pve-devel] [PATCH qemu-server v2 15/32] vm start: move state file handling to dedicated module

[Fiona Ebner]

Signed-off-by: Fiona Ebner <f.ebner at proxmox.com>
---

Changes in v2:
* Re-do on top of change from patch 13/32.

 src/PVE/QemuServer.pm           | 49 ++++++++-------------------------
 src/PVE/QemuServer/StateFile.pm | 47 +++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+), 38 deletions(-)

diff --git a/src/PVE/QemuServer.pm b/src/PVE/QemuServer.pm
index c1133eb8..442adde6 100644
--- a/src/PVE/QemuServer.pm
+++ b/src/PVE/QemuServer.pm
@@ -5946,8 +5946,6 @@ sub vm_start_nolock {
     my $migration_type = $migrate_opts->{type};
     my $nbd_protocol_version = $migrate_opts->{nbd_proto_version} // 0;
 
-    my $res = {};
-
     # clean up leftover reboot request files
     eval { clear_reboot_request($vmid); };
     warn $@ if $@;
@@ -6019,46 +6017,21 @@ sub vm_start_nolock {
             PVE::QemuServer::StateFile::get_migration_ip($nodename, $migrate_opts->{network});
     }
 
+    my $res = {};
+    my $statefile_is_a_volume;
+    my $state_cmdline = [];
     if ($statefile) {
-        if ($statefile eq 'tcp') {
-            my $migrate = $res->{migrate} = { proto => 'tcp' };
-            $migrate->{addr} = "localhost";
-
-            die "no migration type set\n" if !defined($migration_type);
-
-            if ($migration_type eq 'insecure') {
-                $migrate->{addr} = $migration_ip // die "internal error - no migration IP";
-                $migrate->{addr} = "[$migrate->{addr}]" if Net::IP::ip_is_ipv6($migrate->{addr});
-            }
-
-            # see #4501: port reservation should be done close to usage - tell QEMU where to listen
-            # via QMP later
-            push @$cmd, '-incoming', 'defer';
-            push @$cmd, '-S';
-
-        } elsif ($statefile eq 'unix') {
-            # should be default for secure migrations as a ssh TCP forward
-            # tunnel is not deterministic reliable ready and fails regurarly
-            # to set up in time, so use UNIX socket forwards
-            my $migrate = $res->{migrate} = { proto => 'unix' };
-            $migrate->{addr} = "/run/qemu-server/$vmid.migrate";
-            unlink $migrate->{addr};
-
-            $migrate->{uri} = "unix:$migrate->{addr}";
-            push @$cmd, '-incoming', $migrate->{uri};
-            push @$cmd, '-S';
-
-        } elsif (-e $statefile) {
-            push @$cmd, '-loadstate', $statefile;
-        } else {
-            my $statepath = PVE::Storage::path($storecfg, $statefile);
-            push @$vollist, $statefile;
-            push @$cmd, '-loadstate', $statepath;
-        }
+        ($state_cmdline, $res->{migrate}, $statefile_is_a_volume) =
+            PVE::QemuServer::StateFile::statefile_cmdline_option(
+                $storecfg, $vmid, $statefile, $migration_type, $migration_ip,
+            );
+        push @$vollist, $statefile if $statefile_is_a_volume;
     } elsif ($params->{paused}) {
-        push @$cmd, '-S';
+        $state_cmdline = ['-S'];
     }
 
+    push $cmd->@*, $state_cmdline->@*;
+
     my $memory = get_current_memory($conf->{memory});
     my $start_timeout = $params->{timeout} // config_aware_timeout($conf, $memory, $resume);
 
diff --git a/src/PVE/QemuServer/StateFile.pm b/src/PVE/QemuServer/StateFile.pm
index d2cdde46..3c26a9c6 100644
--- a/src/PVE/QemuServer/StateFile.pm
+++ b/src/PVE/QemuServer/StateFile.pm
@@ -29,4 +29,51 @@ sub get_migration_ip {
     return PVE::Cluster::remote_node_ip($nodename, 1);
 }
 
+# $migration_ip must be defined if using insecure TCP migration
+sub statefile_cmdline_option {
+    my ($storecfg, $vmid, $statefile, $migration_type, $migration_ip) = @_;
+
+    my $statefile_is_a_volume = 0;
+    my $res = {};
+    my $cmd = [];
+
+    if ($statefile eq 'tcp') {
+        my $migrate = $res->{migrate} = { proto => 'tcp' };
+        $migrate->{addr} = "localhost";
+
+        die "no migration type set\n" if !defined($migration_type);
+
+        if ($migration_type eq 'insecure') {
+            $migrate->{addr} = $migration_ip // die "internal error - no migration IP";
+            $migrate->{addr} = "[$migrate->{addr}]" if Net::IP::ip_is_ipv6($migrate->{addr});
+        }
+
+        # see #4501: port reservation should be done close to usage - tell QEMU where to listen
+        # via QMP later
+        push @$cmd, '-incoming', 'defer';
+        push @$cmd, '-S';
+
+    } elsif ($statefile eq 'unix') {
+        # should be default for secure migrations as a ssh TCP forward
+        # tunnel is not deterministic reliable ready and fails regurarly
+        # to set up in time, so use UNIX socket forwards
+        my $migrate = $res->{migrate} = { proto => 'unix' };
+        $migrate->{addr} = "/run/qemu-server/$vmid.migrate";
+        unlink $migrate->{addr};
+
+        $migrate->{uri} = "unix:$migrate->{addr}";
+        push @$cmd, '-incoming', $migrate->{uri};
+        push @$cmd, '-S';
+
+    } elsif (-e $statefile) {
+        push @$cmd, '-loadstate', $statefile;
+    } else {
+        my $statepath = PVE::Storage::path($storecfg, $statefile);
+        $statefile_is_a_volume = 1;
+        push @$cmd, '-loadstate', $statepath;
+    }
+
+    return ($cmd, $res->{migrate}, $statefile_is_a_volume);
+}
+
 1;
-- 
2.39.5