[pve-devel] [PATCH v2 pve-common 07/12] test: add tests for path_parent of PVE::Path

[Max Carrara]

What's important to note is that among the cases added are also some
that specifically account for Perl's File::Spec->canonpath treating
paths consisting of a single component that is neither "/" or "." as
the same. This means that e.g. "foo" and "./foo" are both the same
(canonpath returns "foo").

Because canonpath also returns "" instead of "." for the empty path
"", the behaviour of path_parent should be consistent with that of
Perl's canonpath (and in turn therefore also for path_normalize, which
wraps canonpath).

The path_parent function should otherwise work the same as Rust's
std::path::Path::parent [1]. The discrepancies as mentioned above are
checked for by the tests introduced here.

[1]: https://doc.rust-lang.org/std/path/struct.Path.html#method.parent

Signed-off-by: Max Carrara <m.carrara at proxmox.com>
---
Changes v1 --> v2:
  * NEW: Split from patch 02

 test/Path/Makefile             |   1 +
 test/Path/path_parent_tests.pl | 153 +++++++++++++++++++++++++++++++++
 2 files changed, 154 insertions(+)
 create mode 100755 test/Path/path_parent_tests.pl

diff --git a/test/Path/Makefile b/test/Path/Makefile
index 9dd95f1..a2b5bb1 100644
--- a/test/Path/Makefile
+++ b/test/Path/Makefile
@@ -2,6 +2,7 @@ TESTS = \
 	path_components_tests.pl				\
 	path_is_absolute_relative_tests.pl			\
 	path_join_tests.pl					\
+	path_parent_tests.pl					\
 	path_push_tests.pl					\
 
 
diff --git a/test/Path/path_parent_tests.pl b/test/Path/path_parent_tests.pl
new file mode 100755
index 0000000..9dfa301
--- /dev/null
+++ b/test/Path/path_parent_tests.pl
@@ -0,0 +1,153 @@
+#!/usr/bin/env perl
+
+use lib '../../src';
+
+use strict;
+use warnings;
+
+use Test::More;
+
+use PVE::Path;
+
+my $path_parent_cases = [
+    {
+	name => "empty path",
+	path => "",
+	parent => undef,
+    },
+    {
+	name => "root",
+	path => "/",
+	parent => undef,
+    },
+    {
+	name => "current path reference",
+	path => ".",
+	parent => "",
+    },
+    # Why? Because File::Spec->canonpath interprets "./foo" and "foo"
+    # as the same thing, and the parent of "./foo" is "."
+    {
+	name => "single component, relative",
+	path => "foo",
+	parent => ".",
+    },
+    # Same as above!
+    {
+	name => "parent directory reference",
+	path => "..",
+	parent => ".",
+    },
+    {
+	name => "single component, absolute",
+	path => "/foo",
+	parent => "/",
+    },
+    {
+	name => "multiple components, relative",
+	path => "foo/bar/baz/quo/qux",
+	parent => "foo/bar/baz/quo",
+    },
+    {
+	name => "multiple components, absolute",
+	path => "/foo/bar/baz/quo/qux",
+	parent => "/foo/bar/baz/quo",
+    },
+    {
+	name => "multiple components, with redundant current path references",
+	path => "foo/bar/./baz/././quo/./././qux/././.",
+	parent => "foo/bar/./baz/././quo",
+    },
+    {
+	name => "multiple components, with parent directory references",
+	path => "foo/bar/../baz/../../quo/../../../qux/../../..",
+	parent => "foo/bar/../baz/../../quo/../../../qux/../..",
+    },
+    {
+	name => "multiple components, with redundant path separators",
+	path => "foo//bar///baz////quo/////qux//////",
+	parent => "foo//bar///baz////quo",
+    },
+    {
+	name => "root path, with redundant path separators",
+	path => "///////////",
+	parent => undef,
+    },
+    {
+	name => "root path, with redundant current path references",
+	path => "/././././././././././.",
+	parent => undef,
+    },
+    {
+	name => "current path reference, with redundant path separators",
+	path => ".///////////",
+	parent => "",
+    },
+    {
+	name => "current path reference, with redundant current path references",
+	path => "././././././././././.",
+	parent => "",
+    },
+    {
+	name => "multiple components,"
+	    . " with redundant path separators,"
+	    . " with redundant current path references",
+	path => "foo/.///./bar//././////././/baz//././///././././///",
+	parent => "foo/.///./bar",
+    },
+    {
+	name => "path is undef",
+	path => undef,
+	parent => undef,
+	should_throw => 1,
+    },
+];
+
+sub test_path_parent : prototype($) {
+    my ($case) = @_;
+
+    my $name = "path_parent: " . $case->{name};
+
+    my $parent = eval { PVE::Path::path_parent($case->{path}); };
+
+    if ($@) {
+	if ($case->{should_throw}) {
+	    pass($name);
+	    return;
+	}
+
+	fail($name);
+	diag("Failed to get parent from path:\n$@");
+	return;
+    }
+
+    # Note: `!is()` isn't the same as `isnt()` -- we want extra output here
+    # if the check fails; can't do that with `isnt()`
+    if (!is($parent, $case->{parent}, $name)) {
+	diag("=== Expected ===");
+	diag(explain($case->{parent}));
+	diag("=== Got ===");
+	diag(explain($parent));
+    }
+
+    return;
+}
+
+sub main : prototype() {
+    plan(tests => scalar($path_parent_cases->@*));
+
+    for my $case ($path_parent_cases->@*) {
+	eval {
+	    # suppress warnings here to make output less noisy for certain tests if necessary
+	    # local $SIG{__WARN__} = sub {};
+	    test_path_parent($case);
+	};
+	warn "$@\n" if $@;
+    }
+
+    done_testing();
+
+    return;
+}
+
+main();
-- 
2.39.5