[pve-devel] [PATCH container v9 1/1] check_ct_modify_config_perm: improve tag privilege check

[Dominik Csapak]

'normal' tags require 'VM.Config.Options' on '/vm/<vmid>', but not
allowed tags (either limited with 'user-tag-access' or 'privileged-tags'
in the datacenter config) require 'Sys.Modify' on '/'

this patch implements the proper checks on adding/editing/deleting
these permissions

Signed-off-by: Dominik Csapak <d.csapak at proxmox.com>
---
changes from v8:
* adapt to 'get_allowed_tags'
* cache privilege checks (so we don't have to do it when many tags change)
 src/PVE/LXC.pm | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/src/PVE/LXC.pm b/src/PVE/LXC.pm
index 4bbd739..44dee7e 100644
--- a/src/PVE/LXC.pm
+++ b/src/PVE/LXC.pm
@@ -1336,6 +1336,48 @@ sub check_ct_modify_config_perm {
 	} elsif ($opt eq 'hookscript') {
 	    # For now this is restricted to root at pam
 	    raise_perm_exc("changing the hookscript is only allowed for root\@pam");
+	} elsif ($opt eq 'tags') {
+	    my $allowed_tags;
+	    my $privileged_tags;
+	    my $freeform;
+	    my $privileged_user = $rpcenv->check($authuser, '/', ['Sys.Modify'], 1);
+	    my $has_config_options =
+		$rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Options'], 1);
+
+	    my $check_tag_perms = sub {
+		my ($tag) = @_;
+
+		return if $privileged_user;
+
+		$rpcenv->check_vm_perm($authuser, $vmid, undef, ['VM.Config.Options'])
+		    if !$has_config_options;
+
+		if (!defined($allowed_tags) && !defined($privileged_tags) && !defined($freeform)) {
+		    ($allowed_tags, $privileged_tags, $freeform)
+			= PVE::DataCenterConfig::get_allowed_tags($rpcenv, $authuser);
+		}
+
+		if ((!$allowed_tags->{$tag} && !$freeform) || $privileged_tags->{$tag}) {
+		    die "'Sys.Modify' required on '/' for modifying tag $tag\n" if !$privileged_user;
+		}
+	    };
+
+	    my $old_tags = {};
+	    my $new_tags = {};
+
+	    map { $old_tags->{$_} += 1 } PVE::Tools::split_list($oldconf->{$opt} // '');
+	    map { $new_tags->{$_} += 1 } PVE::Tools::split_list($newconf->{$opt});
+
+	    my $check_tags = sub {
+		my ($a, $b) = @_;
+		foreach my $tag (keys %$a) {
+		    next if ($b->{$tag} // 0) == ($a->{$tag} // 0);
+		    $check_tag_perms->($tag);
+		}
+	    };
+
+	    $check_tags->($old_tags, $new_tags);
+	    $check_tags->($new_tags, $old_tags);
 	} else {
 	    $rpcenv->check_vm_perm($authuser, $vmid, $pool, ['VM.Config.Options']);
 	}
-- 
2.30.2