[pve-devel] [PATCH pve-network 1/5] add NetworkConfig.pm (code moved from pve-common)
Alexandre Derumier
aderumier at odiso.com
Fri Jun 7 11:58:28 CEST 2019
Signed-off-by: Alexandre Derumier <aderumier at odiso.com>
---
PVE/Makefile | 6 +
PVE/NetworkConfig.pm | 943 +++++++++++++++++++++++++++++++++++++++++++
2 files changed, 949 insertions(+)
create mode 100644 PVE/NetworkConfig.pm
diff --git a/PVE/Makefile b/PVE/Makefile
index 1fb961d..1b2e52a 100644
--- a/PVE/Makefile
+++ b/PVE/Makefile
@@ -1,4 +1,10 @@
+SOURCES=NetworkConfig.pm
+
+
+PERL5DIR=${DESTDIR}/usr/share/perl5
+
.PHONY: install
install:
+ for i in ${SOURCES}; do install -D -m 0644 $$i ${PERL5DIR}/PVE/$$i; done
make -C Network install
make -C API2 install
diff --git a/PVE/NetworkConfig.pm b/PVE/NetworkConfig.pm
new file mode 100644
index 0000000..b0ed77e
--- /dev/null
+++ b/PVE/NetworkConfig.pm
@@ -0,0 +1,943 @@
+package PVE::NetworkConfig;
+
+use strict;
+use warnings;
+
+use POSIX;
+use IO::File;
+use File::stat;
+use File::Basename;
+use PVE::Network;
+use PVE::Tools;
+use PVE::ProcFSTools;
+use PVE::JSONSchema;
+use JSON;
+use Encode qw(encode decode);
+use PVE::INotify;
+
+PVE::INotify::register_file('interfaces', "/etc/network/interfaces",
+ \&read_etc_network_interfaces,
+ \&write_etc_network_interfaces);
+
+our $bond_modes = { 'balance-rr' => 0,
+ 'active-backup' => 1,
+ 'balance-xor' => 2,
+ 'broadcast' => 3,
+ '802.3ad' => 4,
+ 'balance-tlb' => 5,
+ 'balance-alb' => 6,
+ };
+
+my $ovs_bond_modes = {
+ 'active-backup' => 1,
+ 'balance-slb' => 1,
+ 'lacp-balance-slb' => 1,
+ 'lacp-balance-tcp' => 1,
+};
+
+#sub get_bond_modes {
+# return $bond_modes;
+#}
+
+my $parse_ovs_option = sub {
+ my ($data) = @_;
+
+ my $opts = {};
+ foreach my $kv (split (/\s+/, $data || '')) {
+ my ($k, $v) = split('=', $kv, 2);
+ $opts->{$k} = $v if $k && $v;
+ }
+ return $opts;
+};
+
+my $set_ovs_option = sub {
+ my ($d, %params) = @_;
+
+ my $opts = &$parse_ovs_option($d->{ovs_options});
+
+ foreach my $k (keys %params) {
+ my $v = $params{$k};
+ if ($v) {
+ $opts->{$k} = $v;
+ } else {
+ delete $opts->{$k};
+ }
+ }
+
+ my $res = [];
+ foreach my $k (keys %$opts) {
+ push @$res, "$k=$opts->{$k}";
+ }
+
+ if (my $new = join(' ', @$res)) {
+ $d->{ovs_options} = $new;
+ return $d->{ovs_options};
+ } else {
+ delete $d->{ovs_options};
+ return undef;
+ }
+};
+
+my $extract_ovs_option = sub {
+ my ($d, $name) = @_;
+
+ my $opts = &$parse_ovs_option($d->{ovs_options});
+
+ my $v = delete $opts->{$name};
+
+ my $res = [];
+ foreach my $k (keys %$opts) {
+ push @$res, "$k=$opts->{$k}";
+ }
+
+ if (my $new = join(' ', @$res)) {
+ $d->{ovs_options} = $new;
+ } else {
+ delete $d->{ovs_options};
+ }
+
+ return $v;
+};
+
+my $check_mtu = sub {
+ my ($ifaces, $parent, $child) = @_;
+
+ die "check mtu - missing parent interface\n" if !$parent;
+ die "check mtu - missing child interface\n" if !$child;
+
+ my $cmtu = $ifaces->{$child}->{mtu};
+ return if !$cmtu;
+
+ my $parentdata = $ifaces->{$parent};
+ my $pmtu = $parentdata->{mtu};
+ $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
+ $pmtu = 1500 if !$pmtu;
+
+ die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
+ if $pmtu < $cmtu;
+};
+
+# config => {
+# ifaces => {
+# $ifname => {
+# <optional> exists => BOOL,
+# <optional> active => BOOL,
+# <optional> autostart => BOOL,
+# <auto> priority => INT,
+#
+# type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
+#
+# families => ["inet", "inet6", ...],
+#
+# method => "manual" | "static" | "dhcp" | ... ,
+# address => IP,
+# netmask => SUBNET,
+# broadcast => IP,
+# gateway => IP,
+# comments => [ "..." ],
+#
+# method6 => "manual" | "static" | "dhcp" | ... ,
+# address6 => IP,
+# netmask6 => SUBNET,
+# gateway6 => IP,
+# comments6 => [ "..." ],
+#
+# <known options>, # like bridge_ports, ovs_*
+#
+# # extra/unknown options stored by-family:
+# options => { <inet options>... }
+# options6 => { <inet6 options>... }
+# }
+# },
+# options => [
+# # mappings end up here as well, as we don't need to understand them
+# [priority,line]
+# ]
+# }
+sub read_etc_network_interfaces {
+ my ($filename, $fh) = @_;
+ my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
+ my $active = PVE::ProcFSTools::get_active_network_interfaces();
+ return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
+}
+
+sub __read_etc_network_interfaces {
+ my ($fh, $proc_net_dev, $active_ifaces) = @_;
+
+ my $config = {};
+ my $ifaces = $config->{ifaces} = {};
+ my $options = $config->{options} = [];
+
+ my $options_alternatives = {
+ 'bond-slaves' => 'slaves',
+ 'bond_slaves' => 'slaves',
+ 'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
+ 'bond-mode' => 'bond_mode',
+ 'bond-miimon' =>'bond_miimon',
+ 'bridge-vlan-aware' => 'bridge_vlan_aware',
+ 'bridge-fd' => 'bridge_fd',
+ 'bridge-stp' => 'bridge_stp',
+ 'bridge-ports' => 'bridge_ports',
+ 'bridge-vids' => 'bridge_vids'
+ };
+
+ my $line;
+
+ if ($proc_net_dev) {
+ while (defined ($line = <$proc_net_dev>)) {
+ if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
+ $ifaces->{$1}->{exists} = 1;
+ }
+ }
+ close($proc_net_dev);
+ }
+
+ # we try to keep order inside the file
+ my $priority = 2; # 1 is reserved for lo
+
+ SECTION: while (defined ($line = <$fh>)) {
+ chomp ($line);
+ next if $line =~ m/^\s*#/;
+
+ if ($line =~ m/^\s*auto\s+(.*)$/) {
+ my @aa = split (/\s+/, $1);
+
+ foreach my $a (@aa) {
+ $ifaces->{$a}->{autostart} = 1;
+ }
+
+ } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
+ my $i = $1;
+ my $family = $2;
+ my $f = { method => $3 }; # by family, merged to $d with a $suffix
+ (my $suffix = $family) =~ s/^inet//;
+
+ foreach my $existing_family (@{$ifaces->{$i}->{'families'}}) {
+ die "interface $i with family $family already exist" if $family eq $existing_family;
+ }
+
+ my $d = $ifaces->{$i} ||= {};
+ $d->{priority} = $priority++ if !$d->{priority};
+ push @{$d->{families}}, $family;
+
+ while (defined ($line = <$fh>)) {
+ chomp $line;
+ if ($line =~ m/^\s*#(.*?)\s*$/) {
+ $f->{comments} = '' if !$f->{comments};
+ my $comment = decode('UTF-8', $1);
+ $f->{comments} .= "$comment\n";
+ } elsif ($line =~ m/^\s*(?:iface\s
+ |mapping\s
+ |auto\s
+ |allow-
+ |source\s
+ |source-directory\s
+ )/x) {
+ last;
+ } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
+ my $option = $1;
+ my ($id, $value) = ($2, $3);
+
+ $id = $options_alternatives->{$id} if $options_alternatives->{$id};
+
+ my $simple_options = {
+ 'mtu' => 1,
+ 'ovs_type' => 1,
+ 'ovs_options' => 1,
+ 'ovs_bridge' => 1,
+ 'ovs_bonds' => 1,
+ 'ovs_ports' => 1,
+ 'bridge_fd' => 1,
+ 'bridge_vids' => 1,
+ 'bridge-access' => 1,
+ 'bridge-learning' => 1,
+ 'bridge-arp-nd-suppress' => 1,
+ 'bridge-unicast-flood' => 1,
+ 'bridge-multicast-flood' => 1,
+ 'bond_miimon' => 1,
+ 'bond_xmit_hash_policy' => 1,
+ 'uplink-id' => 1,
+ 'vrf' => 1,
+ 'vrf-table' => 1,
+ 'vlan-protocol' => 1,
+ 'vxlan-id' => 1,
+ 'vxlan-svcnodeip' => 1,
+ 'vxlan-physdev' => 1,
+ 'vxlan-local-tunnelip' => 1 };
+
+ if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
+ $f->{$id} = $value;
+ } elsif ($simple_options->{$id}) {
+ $d->{$id} = $value;
+ } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
+ my $devs = {};
+ foreach my $p (split (/\s+/, $value)) {
+ next if $p eq 'none';
+ $devs->{$p} = 1;
+ }
+ my $str = join (' ', sort keys %{$devs});
+ if ($d->{$id}) {
+ $d->{$id} .= ' ' . $str if $str;
+ } else {
+ $d->{$id} = $str || '';
+ }
+ } elsif ($id eq 'bridge_stp') {
+ if ($value =~ m/^\s*(on|yes)\s*$/i) {
+ $d->{$id} = 'on';
+ } else {
+ $d->{$id} = 'off';
+ }
+ } elsif ($id eq 'bridge_vlan_aware') {
+ $d->{$id} = 1;
+ } elsif ($id eq 'bond_mode') {
+ # always use names
+ foreach my $bm (keys %$bond_modes) {
+ my $id = $bond_modes->{$bm};
+ if ($id eq $value) {
+ $value = $bm;
+ last;
+ }
+ }
+ $d->{$id} = $value;
+ } elsif ($id eq 'vxlan-remoteip') {
+ push @{$d->{$id}}, $value;
+ } else {
+ push @{$f->{options}}, $option;
+ }
+ } else {
+ last;
+ }
+ }
+ $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
+ last SECTION if !defined($line);
+ redo SECTION;
+ } elsif ($line =~ /\w/) {
+ push @$options, [$priority++, $line];
+ }
+ }
+
+ foreach my $ifname (@$active_ifaces) {
+ if (my $iface = $ifaces->{$ifname}) {
+ $iface->{active} = 1;
+ }
+ }
+
+ if (!$ifaces->{lo}) {
+ $ifaces->{lo}->{priority} = 1;
+ $ifaces->{lo}->{method} = 'loopback';
+ $ifaces->{lo}->{type} = 'loopback';
+ $ifaces->{lo}->{autostart} = 1;
+ }
+
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($iface =~ m/^bond\d+$/) {
+ if (!$d->{ovs_type}) {
+ $d->{type} = 'bond';
+ } elsif ($d->{ovs_type} eq 'OVSBond') {
+ $d->{type} = $d->{ovs_type};
+ # translate: ovs_options => bond_mode
+ $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
+ my $lacp = &$extract_ovs_option($d, 'lacp');
+ if ($lacp && $lacp eq 'active') {
+ if ($d->{'bond_mode'} eq 'balance-slb') {
+ $d->{'bond_mode'} = 'lacp-balance-slb';
+ }
+ }
+ # Note: balance-tcp needs lacp
+ if ($d->{'bond_mode'} eq 'balance-tcp') {
+ $d->{'bond_mode'} = 'lacp-balance-tcp';
+ }
+ my $tag = &$extract_ovs_option($d, 'tag');
+ $d->{ovs_tag} = $tag if defined($tag);
+ } else {
+ $d->{type} = 'unknown';
+ }
+ } elsif ($iface =~ m/^(vmbr|vnet)\d+$/) {
+ if (!$d->{ovs_type}) {
+ $d->{type} = 'bridge';
+
+ if (!defined ($d->{bridge_fd})) {
+ $d->{bridge_fd} = 0;
+ }
+ if (!defined ($d->{bridge_stp})) {
+ $d->{bridge_stp} = 'off';
+ }
+ } elsif ($d->{ovs_type} eq 'OVSBridge') {
+ $d->{type} = $d->{ovs_type};
+ } else {
+ $d->{type} = 'unknown';
+ }
+ } elsif ($iface =~ m/^(\S+):\d+$/) {
+ $d->{type} = 'alias';
+ if (defined ($ifaces->{$1})) {
+ $d->{exists} = $ifaces->{$1}->{exists};
+ } else {
+ $ifaces->{$1}->{exists} = 0;
+ $d->{exists} = 0;
+ }
+ } elsif ($iface =~ m/^(\S+)\.\d+$/) {
+ $d->{type} = 'vlan';
+ if (defined ($ifaces->{$1})) {
+ $d->{exists} = $ifaces->{$1}->{exists};
+ } else {
+ $ifaces->{$1}->{exists} = 0;
+ $d->{exists} = 0;
+ }
+ } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
+ if (!$d->{ovs_type}) {
+ $d->{type} = 'eth';
+ } elsif ($d->{ovs_type} eq 'OVSPort') {
+ $d->{type} = $d->{ovs_type};
+ my $tag = &$extract_ovs_option($d, 'tag');
+ $d->{ovs_tag} = $tag if defined($tag);
+ } else {
+ $d->{type} = 'unknown';
+ }
+ } elsif ($iface =~ m/^lo$/) {
+ $d->{type} = 'loopback';
+ } else {
+ if ($d->{'vxlan-id'}) {
+ $d->{type} = 'vxlan';
+ } elsif ($d->{'vrf-table'}) {
+ $d->{type} = 'vrfint';
+ } elsif (!$d->{ovs_type}) {
+ $d->{type} = 'unknown';
+ } elsif ($d->{ovs_type} eq 'OVSIntPort') {
+ $d->{type} = $d->{ovs_type};
+ my $tag = &$extract_ovs_option($d, 'tag');
+ $d->{ovs_tag} = $tag if defined($tag);
+ }
+ }
+
+ # map address and netmask to cidr
+ if ($d->{address}) {
+ if ($d->{netmask} =~ m/^\d+$/) { # e.g. netmask 20
+ $d->{cidr} = $d->{address} . "/" . $d->{netmask};
+ } elsif ($d->{netmask} &&
+ (my $cidr = PVE::JSONSchema::get_netmask_bits($d->{netmask}))) { # e.g. netmask 255.255.255.0
+ $d->{cidr} = $d->{address} . "/" . $cidr;
+ } elsif ($d->{address} =~ m!^(.*)/(\d+)$!) {
+ $d->{cidr} = $d->{address};
+ $d->{address} = $1;
+ $d->{netmask} = $2;
+ } else {
+ $d->{cidr} = $d->{address};
+ }
+ }
+
+ # map address6 and netmask6 to cidr6
+ if ($d->{address6}) {
+ $d->{cidr6} = $d->{address6};
+ if ($d->{netmask6}) {
+ $d->{cidr6} .= "/" . $d->{netmask6};
+ } elsif ($d->{address6} =~ m!^(.*)/(\d+)$!) {
+ $d->{address6} = $1;
+ $d->{netmask6} = $2;
+ }
+ }
+
+ $d->{method} = 'manual' if !$d->{method};
+ $d->{method6} = 'manual' if !$d->{method6};
+
+ $d->{families} ||= ['inet'];
+ }
+
+ # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
+ # from the {options} hash for them to be removed correctly.
+ @$options = grep {defined($_)} map {
+ my ($pri, $line) = @$_;
+ if ($line =~ /^allow-(\S+)\s+(.*)$/) {
+ my $bridge = $1;
+ my @ports = split(/\s+/, $2);
+ if (defined(my $br = $ifaces->{$bridge})) {
+ # if this port is part of a bridge, remove it
+ my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
+ @ports = grep { not $in_ovs_ports{$_} } @ports;
+ }
+ # create the allow line for the remaining ports, or delete if empty
+ if (@ports) {
+ [$pri, "allow-$bridge " . join(' ', @ports)];
+ } else {
+ undef;
+ }
+ } else {
+ # don't modify other lines
+ $_;
+ }
+ } @$options;
+
+ return $config;
+}
+
+sub __interface_to_string {
+ my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
+
+ (my $suffix = $family) =~ s/^inet//;
+
+ return '' if !($d && $d->{"method$suffix"});
+
+ my $raw = '';
+
+ $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
+ $raw .= "\taddress " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
+ $raw .= "\tnetmask " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
+ $raw .= "\tgateway " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
+ $raw .= "\tbroadcast " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
+
+ my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
+ comments => 1, autostart => 1, options => 1,
+ address => 1, netmask => 1, gateway => 1, broadcast => 1,
+ method6 => 1, families => 1, options6 => 1,
+ address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1, 'uplink-id' => 1 };
+
+ if (!$first_block) {
+ # not printing out options
+ } elsif ($d->{type} eq 'bridge') {
+
+ $d->{bridge_ports} =~ s/[;,\s]+/ /g;
+ my $ports = $d->{bridge_ports} || 'none';
+ $raw .= "\tbridge-ports $ports\n";
+ $done->{bridge_ports} = 1;
+
+ my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
+ $raw .= "\tbridge-stp $v\n";
+ $done->{bridge_stp} = 1;
+
+ $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
+ $raw .= "\tbridge-fd $v\n";
+ $done->{bridge_fd} = 1;
+
+ if( defined($d->{bridge_vlan_aware})) {
+ $raw .= "\tbridge-vlan-aware yes\n";
+ $v = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
+ $raw .= "\tbridge-vids $v\n";
+ }
+ $done->{bridge_vlan_aware} = 1;
+ $done->{bridge_vids} = 1;
+
+ } elsif ($d->{type} eq 'bond') {
+
+ $d->{slaves} =~ s/[;,\s]+/ /g;
+ my $slaves = $d->{slaves} || 'none';
+ $raw .= "\tbond-slaves $slaves\n";
+ $done->{slaves} = 1;
+
+ my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
+ $raw .= "\tbond-miimon $v\n";
+ $done->{'bond_miimon'} = 1;
+
+ $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
+ $raw .= "\tbond-mode $v\n";
+ $done->{'bond_mode'} = 1;
+
+ if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
+ ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
+ $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
+ }
+ $done->{'bond_xmit_hash_policy'} = 1;
+ } elsif ($d->{type} eq 'vlan') {
+ die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n"
+ if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
+
+ } elsif ($d->{type} eq 'vrfint') {
+
+ my $vrftable = $d->{'vrf-table'};
+ if ($vrftable) {
+ if ($vrftable =~ m/(\d+)$/) {
+ die "$iface: vrf-table $vrftable must be between 1001 and 1255" if ($vrftable < 1001 || $vrftable > 1255);
+ } else {
+ die "$iface: vrf-table $vrftable need to be auto if no tableid is defined" if $vrftable ne 'auto';
+ }
+ }
+
+ } elsif ($d->{type} eq 'vxlan') {
+
+ foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
+ $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
+ $done->{$k} = 1;
+ }
+
+ if ($d->{'vxlan-remoteip'}) {
+ foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
+ $raw .= "\tvxlan-remoteip $remoteip\n";
+ }
+ $done->{'vxlan-remoteip'} = 1;
+ }
+ } elsif ($d->{type} eq 'OVSBridge') {
+
+ $raw .= "\tovs_type $d->{type}\n";
+ $done->{ovs_type} = 1;
+
+ $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
+ $done->{ovs_ports} = 1;
+ } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
+ $d->{type} eq 'OVSBond') {
+
+ $d->{autostart} = 0; # started by the bridge
+
+ if (defined($d->{ovs_tag})) {
+ &$set_ovs_option($d, tag => $d->{ovs_tag});
+ }
+ $done->{ovs_tag} = 1;
+
+ if ($d->{type} eq 'OVSBond') {
+
+ $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
+
+ $ovs_bond_modes->{$d->{bond_mode}} ||
+ die "OVS does not support bond mode '$d->{bond_mode}\n";
+
+ if ($d->{bond_mode} eq 'lacp-balance-slb') {
+ &$set_ovs_option($d, lacp => 'active');
+ &$set_ovs_option($d, bond_mode => 'balance-slb');
+ } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
+ &$set_ovs_option($d, lacp => 'active');
+ &$set_ovs_option($d, bond_mode => 'balance-tcp');
+ } else {
+ &$set_ovs_option($d, lacp => undef);
+ &$set_ovs_option($d, bond_mode => $d->{bond_mode});
+ }
+ $done->{bond_mode} = 1;
+
+ $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
+ $done->{ovs_bonds} = 1;
+ }
+
+ $raw .= "\tovs_type $d->{type}\n";
+ $done->{ovs_type} = 1;
+
+ if ($d->{ovs_bridge}) {
+
+ if ($ifupdown2) {
+ $raw = "auto $iface\n$raw";
+ } else {
+ $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
+ }
+
+ $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
+ $done->{ovs_bridge} = 1;
+ }
+ }
+
+ if ($first_block) {
+ # print other settings
+ foreach my $k (sort keys %$d) {
+ next if $done->{$k};
+ next if !$d->{$k};
+ $raw .= "\t$k $d->{$k}\n";
+ }
+ }
+
+ foreach my $option (@{$d->{"options$suffix"}}) {
+ $raw .= "\t$option\n";
+ }
+
+ # add comments
+ my $comments = $d->{"comments$suffix"} || '';
+ foreach my $cl (split(/\n/, $comments)) {
+ $raw .= "#$cl\n";
+ }
+
+ $raw .= "\n";
+
+ return $raw;
+}
+
+
+sub write_etc_network_interfaces {
+ my ($filename, $fh, $config) = @_;
+ my $ifupdown2 = -e '/usr/share/ifupdown2';
+ my $raw = __write_etc_network_interfaces($config, $ifupdown2);
+ PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
+}
+sub __write_etc_network_interfaces {
+ my ($config, $ifupdown2) = @_;
+
+ my $ifaces = $config->{ifaces};
+ my @options = @{$config->{options}};
+
+ my $used_ports = {};
+
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+
+ delete $d->{cidr};
+ delete $d->{cidr6};
+
+ my $ports = '';
+ foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
+ $ports .= " $d->{$k}" if $d->{$k};
+ }
+
+ foreach my $p (PVE::Tools::split_list($ports)) {
+ die "port '$p' is already used on interface '$used_ports->{$p}'\n"
+ if $used_ports->{$p} && $used_ports->{$p} ne $iface;
+ $used_ports->{$p} = $iface;
+ }
+ }
+
+ # delete unused OVS ports
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
+ $d->{type} eq 'OVSBond') {
+ my $brname = $used_ports->{$iface};
+ if (!$brname || !$ifaces->{$brname}) {
+ if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
+ $ifaces->{$iface} = { type => 'eth',
+ exists => 1,
+ method => 'manual',
+ families => ['inet'] };
+ } else {
+ delete $ifaces->{$iface};
+ }
+ next;
+ }
+ my $bd = $ifaces->{$brname};
+ if ($bd->{type} ne 'OVSBridge') {
+ delete $ifaces->{$iface};
+ next;
+ }
+ }
+ }
+
+ # create OVS bridge ports
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
+ foreach my $p (split (/\s+/, $d->{ovs_ports})) {
+ my $n = $ifaces->{$p};
+ die "OVS bridge '$iface' - unable to find port '$p'\n"
+ if !$n;
+ $n->{autostart} = 0;
+ if ($n->{type} eq 'eth') {
+ $n->{type} = 'OVSPort';
+ $n->{ovs_bridge} = $iface;
+ } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
+ $n->{type} eq 'OVSIntPort') {
+ $n->{ovs_bridge} = $iface;
+ } else {
+ die "interface '$p' is not defined as OVS port/bond\n";
+ }
+
+ &$check_mtu($ifaces, $iface, $p);
+ }
+ }
+ }
+
+ # check OVS bond ports
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
+ foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
+ my $n = $ifaces->{$p};
+ die "OVS bond '$iface' - unable to find slave '$p'\n"
+ if !$n;
+ die "OVS bond '$iface' - wrong interface type on slave '$p' " .
+ "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
+ &$check_mtu($ifaces, $iface, $p);
+ }
+ }
+ }
+
+ # check bond
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{type} eq 'bond' && $d->{slaves}) {
+ foreach my $p (split (/\s+/, $d->{slaves})) {
+ my $n = $ifaces->{$p};
+
+ die "bond '$iface' - unable to find slave '$p'\n"
+ if !$n;
+ die "bond '$iface' - wrong interface type on slave '$p' " .
+ "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
+ &$check_mtu($ifaces, $iface, $p);
+ }
+ }
+ }
+
+ # check vxlan
+ my $vxlans = {};
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+
+ if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
+ my $vxlanid = $d->{'vxlan-id'};
+ die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
+ $vxlans->{$vxlanid} = $iface;
+ }
+
+ my $ips = 0;
+ ++$ips if defined $d->{'vxlan-svcnodeip'};
+ ++$ips if defined $d->{'vxlan-remoteip'};
+ ++$ips if defined $d->{'vxlan-local-tunnelip'};
+ if ($ips > 1) {
+ die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
+ }
+
+ if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
+ die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
+ }
+ #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
+ }
+
+ # check vlan
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{type} eq 'vlan' && $iface =~ m/^(\S+)\.\d+$/) {
+ my $p = $1;
+ my $n = $ifaces->{$p};
+
+ die "vlan '$iface' - unable to find parent '$p'\n"
+ if !$n;
+
+ if ($n->{type} eq 'bridge' && !$n->{bridge_vlan_aware}) {
+ die "vlan '$iface' - bridge vlan aware is not enabled on parent '$p'\n";
+ } elsif ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
+ die "vlan '$iface' - wrong interface type on parent '$p' " .
+ "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
+ }
+
+ &$check_mtu($ifaces, $p, $iface);
+
+ }
+ }
+
+ # check vrf
+ my $vrfs = {};
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{'type'} eq 'vrfint') {
+ die "vrf $iface already exist" if $vrfs->{$iface};
+ $vrfs->{$iface} = 1;
+ }
+ }
+
+ # check uplink
+ my $uplinks = {};
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if (my $uplinkid = $d->{'uplink-id'}) {
+ die "iface '$iface' - uplink-id $uplinkid is only allowed on physical and linux bond interfaces\n"
+ if $d->{type} ne 'eth' && $d->{type} ne 'bond' && $d->{type} ne 'vlan';
+
+ die "iface '$iface' - uplink-id $uplinkid is already assigned on '$uplinks->{$uplinkid}'\n"
+ if $uplinks->{$uplinkid};
+
+ $uplinks->{$uplinkid} = $iface;
+ }
+ }
+
+ # check bridgeport option
+ my $bridgeports = {};
+ my $bridges = {};
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+ if ($d->{type} eq 'bridge') {
+ foreach my $p (split (/\s+/, $d->{bridge_ports})) {
+ $p =~ s/\.\d+$//;
+ my $n = $ifaces->{$p};
+ die "bridge '$iface' - unable to find bridge port '$p'\n"
+ if !$n;
+ &$check_mtu($ifaces, $iface, $p);
+ $bridgeports->{$p} = $iface;
+ }
+ $bridges->{$iface} = $d;
+ }
+ }
+
+ foreach my $iface (keys %$ifaces) {
+ my $d = $ifaces->{$iface};
+
+ foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
+ die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
+ if $d->{$k} && !$bridgeports->{$iface};
+ }
+
+ if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
+ die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
+ }
+
+ die "vrf $d->{vrf} don't exist" if $d->{vrf} && !$vrfs->{$d->{vrf}};
+ }
+
+ my $raw = <<'NETWORKDOC';
+# network interface settings; autogenerated
+# Please do NOT modify this file directly, unless you know what
+# you're doing.
+#
+# If you want to manage parts of the network configuration manually,
+# please utilize the 'source' or 'source-directory' directives to do
+# so.
+# PVE will preserve these directives, but will NOT read its network
+# configuration from sourced files, so do not attempt to move any of
+# the PVE managed interfaces into external files!
+
+NETWORKDOC
+
+ my $printed = {};
+
+ my $if_type_hash = {
+ loopback => 100000,
+ eth => 200000,
+ OVSPort => 200000,
+ OVSIntPort => 200000,
+ bond => 300000,
+ bridge => 400000,
+ OVSBridge => 400000,
+ vxlan => 500000,
+ vrfint => 600000
+ };
+
+ my $lookup_type_prio = sub {
+ my ($iface, $ifaces) = @_;
+
+ my ($rootiface, @rest) = split(/[.:]/, $iface);
+ my $childlevel = scalar(@rest);
+ my $n = $ifaces->{$rootiface};
+ my $pri = $if_type_hash->{$n->{type}} + $childlevel
+ if $n->{type} && $n->{type} ne 'unknown';
+
+ return $pri;
+ };
+
+ foreach my $iface (sort {
+ my $ref1 = $ifaces->{$a};
+ my $ref2 = $ifaces->{$b};
+ my $tp1 = &$lookup_type_prio($a, $ifaces);
+ my $tp2 = &$lookup_type_prio($b, $ifaces);
+
+ # Only recognized types are in relation to each other. If one type
+ # is unknown then only consider the interfaces' priority attributes.
+ $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
+
+ my $p1 = $tp1 + ($ref1->{priority} // 50000);
+ my $p2 = $tp2 + ($ref2->{priority} // 50000);
+
+ return $p1 <=> $p2 if $p1 != $p2;
+
+ return $a cmp $b;
+ } keys %$ifaces) {
+ next if $printed->{$iface};
+
+ my $d = $ifaces->{$iface};
+ my $pri = $d->{priority} // 0;
+ if (@options && $options[0]->[0] < $pri) {
+ do {
+ $raw .= (shift @options)->[1] . "\n";
+ } while (@options && $options[0]->[0] < $pri);
+ $raw .= "\n";
+ }
+
+ $printed->{$iface} = 1;
+ $raw .= "auto $iface\n" if $d->{autostart};
+ my $i = 0; # some options should be printed only once
+ $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
+ }
+
+ $raw .= $_->[1] . "\n" foreach @options;
+ return $raw;
+}
+
+1;
--
2.20.1
More information about the pve-devel
mailing list