[pve-devel] [PATCH storage 1/3] Diskmanage: change parttype uuid detection

[Dominik Csapak]

previously ceph included a udev rule to populate
/dev/disk/by-parttypeuuid/

but not anymore, so we now use 'lsblk --json -o path,parttype' to
get a mapping between parttype uuid and partition

fix the test by simulating empty lsblk output

Signed-off-by: Dominik Csapak <d.csapak at proxmox.com>
---
 PVE/Diskmanage.pm     | 108 ++++++++++++++++++++++++++++--------------
 test/disklist_test.pm |   9 +++-
 2 files changed, 79 insertions(+), 38 deletions(-)

diff --git a/PVE/Diskmanage.pm b/PVE/Diskmanage.pm
index 0deb1a6..8230aad 100644
--- a/PVE/Diskmanage.pm
+++ b/PVE/Diskmanage.pm
@@ -6,6 +6,7 @@ use PVE::ProcFSTools;
 use Data::Dumper;
 use Cwd qw(abs_path);
 use Fcntl ':mode';
+use JSON;
 
 use PVE::Tools qw(extract_param run_command file_get_contents file_read_firstline dir_glob_regex dir_glob_foreach trim);
 
@@ -15,6 +16,7 @@ my $SGDISK = "/sbin/sgdisk";
 my $PVS = "/sbin/pvs";
 my $LVS = "/sbin/lvs";
 my $UDEVADM = "/bin/udevadm";
+my $LSBLK = "/bin/lsblk";
 
 sub verify_blockdev_path {
     my ($rel_path) = @_;
@@ -154,7 +156,38 @@ sub get_smart_data {
     return $smartdata;
 }
 
+sub get_lsblk_info() {
+    my $cmd = [$LSBLK, '--json', '-o', 'path,parttype'];
+    my $output = "";
+    my $res = {};
+    eval {
+	run_command($cmd, outfunc => sub {
+	    $output .= "$_\n";
+	});
+    };
+    warn "$@\n" if $@;
+    my $list = [];
+    eval {
+	$list = decode_json($output);
+	$list = $list->{blockdevices}; # pull out the device list
+    };
+    warn "$@\n" if $@;
+
+    for my $dev (@$list) {
+	next if !($dev->{parttype});
+	my $type = $dev->{parttype};
+	my $path = $dev->{path};
+	if (!$res->{$type}) {
+	    $res->{$type} = [];
+	}
+	push @{$res->{$type}}, $path;
+    }
+
+    return $res;
+}
+
 sub get_zfs_devices {
+    my ($lsblk) = @_;
     my $list = {};
 
     return {} if ! -x $ZPOOL;
@@ -176,19 +209,24 @@ sub get_zfs_devices {
     # because maybe zfs tools are not installed
     warn "$@\n" if $@;
 
-    my $applezfsuuid = "6a898cc3-1dd2-11b2-99a6-080020736631";
-    my $bsdzfsuuid = "516e7cba-6ecf-11d6-8ff8-00022d09712b";
+    my $uuids = [
+	"6a898cc3-1dd2-11b2-99a6-080020736631", # apple
+	"516e7cba-6ecf-11d6-8ff8-00022d09712b", # bsd
+    ];
 
-    dir_glob_foreach('/dev/disk/by-parttypeuuid', "($applezfsuuid|$bsdzfsuuid)\..+", sub {
-	my ($entry) = @_;
-	my $real_dev = abs_path("/dev/disk/by-parttypeuuid/$entry");
-	$list->{$real_dev} = 1;
-    });
+    for my $uuid (@$uuids) {
+	if ($lsblk->{$uuid}) {
+	    for my $dev (@{$lsblk->{$uuid}}) {
+		$list->{$dev} = 1;
+	    }
+	}
+    }
 
     return $list;
 }
 
 sub get_lvm_devices {
+    my ($lsblk) = @_;
     my $list = {};
     eval {
 	run_command([$PVS, '--noheadings', '--readonly', '-o', 'pv_name'], outfunc => sub{
@@ -205,39 +243,35 @@ sub get_lvm_devices {
     warn "$@\n" if $@;
 
     my $lvmuuid = "e6d6d379-f507-44c2-a23c-238f2a3df928";
-
-    dir_glob_foreach('/dev/disk/by-parttypeuuid', "$lvmuuid\..+", sub {
-	my ($entry) = @_;
-	my $real_dev = abs_path("/dev/disk/by-parttypeuuid/$entry");
-	$list->{$real_dev} = 1;
-    });
+    if ($lsblk->{$lvmuuid}) {
+	for my $dev (@{$lsblk->{$lvmuuid}}) {
+	    $list->{$dev} = 1;
+	}
+    }
 
     return $list;
 }
 
 sub get_ceph_journals {
-    my $journalhash = {};
-
-    my $journal_uuid = '45b0969e-9b03-4f30-b4c6-b4b80ceff106';
-    my $db_uuid = '30cd0809-c2b2-499c-8879-2d6b78529876';
-    my $wal_uuid = '5ce17fce-4087-4169-b7ff-056cc58473f9';
-    my $block_uuid = 'cafecafe-9b03-4f30-b4c6-b4b80ceff106';
-
-    dir_glob_foreach('/dev/disk/by-parttypeuuid', "($journal_uuid|$db_uuid|$wal_uuid|$block_uuid)\..+", sub {
-	my ($entry, $type) = @_;
-	my $real_dev = abs_path("/dev/disk/by-parttypeuuid/$entry");
-	if ($type eq $journal_uuid) {
-	    $journalhash->{$real_dev} = 1;
-	} elsif ($type eq $db_uuid) {
-	    $journalhash->{$real_dev} = 2;
-	} elsif ($type eq $wal_uuid) {
-	    $journalhash->{$real_dev} = 3;
-	} elsif ($type eq $block_uuid) {
-	    $journalhash->{$real_dev} = 4;
+    my ($lsblk) = @_;
+    my $list = {};
+
+    my $uuids = [
+	'45b0969e-9b03-4f30-b4c6-b4b80ceff106', # journal
+	'30cd0809-c2b2-499c-8879-2d6b78529876', # db
+	'5ce17fce-4087-4169-b7ff-056cc58473f9', # wal
+	'cafecafe-9b03-4f30-b4c6-b4b80ceff106', # block
+    ];
+
+    for my $uuid (@$uuids) {
+	if ($lsblk->{$uuid}) {
+	    for my $dev (@{$lsblk->{$uuid}}) {
+		$list->{$dev} = 1;
+	    }
 	}
-    });
+    }
 
-    return $journalhash;
+    return $list;
 }
 
 # reads the lv_tags and matches them with the devices
@@ -442,12 +476,14 @@ sub get_disks {
 	return $mounted->{$dev};
     };
 
-    my $journalhash = get_ceph_journals();
+    my $lsblkinfo = get_lsblk_info();
+
+    my $journalhash = get_ceph_journals($lsblkinfo);
     my $ceph_volume_infos = get_ceph_volume_infos();
 
-    my $zfslist = get_zfs_devices();
+    my $zfslist = get_zfs_devices($lsblkinfo);
 
-    my $lvmlist = get_lvm_devices();
+    my $lvmlist = get_lvm_devices($lsblkinfo);
 
     my $disk_regex = ".*";
     if (defined($disks)) {
diff --git a/test/disklist_test.pm b/test/disklist_test.pm
index 527e882..9cb6763 100644
--- a/test/disklist_test.pm
+++ b/test/disklist_test.pm
@@ -54,9 +54,14 @@ sub mocked_run_command {
 	    @$outputlines = split(/\n/, read_test_file('pvs'));
 	} elsif ($cmd->[0] =~ m/lvs/i) {
 	    @$outputlines = split(/\n/, read_test_file('lvs'));
+	} elsif ($cmd->[0] =~ m/lsblk/i) {
+	    my $content = read_test_file('lsblk');
+	    if ($content eq '') {
+		$content = '{}';
+	    }
+	    @$outputlines = split(/\n/, $content);
 	} else {
-	    print "unexpected run_command call: '@$cmd', aborting\n";
-	    die;
+	    die "unexpected run_command call: '@$cmd', aborting\n";
 	}
     } else {
 	print "unexpected run_command call: '@$cmd', aborting\n";
-- 
2.20.1