[pve-devel] [PATCH http-server 2/4] Move read_proxy_conf from PVE::API2Tools

Stoiko Ivanov s.ivanov at proxmox.com
Fri Feb 22 19:51:59 CET 2019


into new module PVE::APIServer::Utils.
It now takes the proxy_name (e.g. pveproxy, pmgproxy) as variable to be used
for the configfile location (/etc/default/$proxy_name)

This serves as preparation to make pmgproxy configurable in the same way as
pveproxy.

Signed-off-by: Stoiko Ivanov <s.ivanov at proxmox.com>
---
 PVE/APIServer/Utils.pm | 55 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 PVE/APIServer/Utils.pm

diff --git a/PVE/APIServer/Utils.pm b/PVE/APIServer/Utils.pm
new file mode 100644
index 0000000..36b9c1f
--- /dev/null
+++ b/PVE/APIServer/Utils.pm
@@ -0,0 +1,55 @@
+package PVE::APIServer::Utils;
+
+use strict;
+use warnings;
+
+use Net::IP;
+
+sub read_proxy_config {
+    my ($proxy_name) = @_;
+
+    my $conffile = "/etc/default/$proxy_name";
+
+    # Note: evaluate with bash
+    my $shcmd = ". $conffile;\n";
+    $shcmd .= 'echo \"ALLOW_FROM:\$ALLOW_FROM\";';
+    $shcmd .= 'echo \"DENY_FROM:\$DENY_FROM\";';
+    $shcmd .= 'echo \"POLICY:\$POLICY\";';
+    $shcmd .= 'echo \"CIPHERS:\$CIPHERS\";';
+    $shcmd .= 'echo \"DHPARAMS:\$DHPARAMS\";';
+    $shcmd .= 'echo \"HONOR_CIPHER_ORDER:\$HONOR_CIPHER_ORDER\";';
+    $shcmd .= 'echo \"COMPRESSION:\$COMPRESSION\";';
+
+    my $data = -f $conffile ? `bash -c "$shcmd"` : '';
+
+    my $res = {};
+
+    while ($data =~ s/^(.*)\n//) {
+	my ($key, $value) = split(/:/, $1, 2);
+	next if !defined($value) || $value eq '';
+	if ($key eq 'ALLOW_FROM' || $key eq 'DENY_FROM') {
+	    my $ips = [];
+	    foreach my $ip (split(/,/, $value)) {
+		$ip = "0/0" if $ip eq 'all';
+		push @$ips, Net::IP->new($ip) || die Net::IP::Error() . "\n";
+	    }
+	    $res->{$key} = $ips;
+	} elsif ($key eq 'POLICY') {
+	    die "unknown policy '$value'\n" if $value !~ m/^(allow|deny)$/;
+	    $res->{$key} = $value;
+	} elsif ($key eq 'CIPHERS') {
+	    $res->{$key} = $value;
+	} elsif ($key eq 'DHPARAMS') {
+	    $res->{$key} = $value;
+	} elsif ($key eq 'HONOR_CIPHER_ORDER' || $key eq 'COMPRESSION') {
+	    die "unknown value '$value' - use 0 or 1\n" if $value !~ m/^(0|1)$/;
+	    $res->{$key} = $value;
+	} else {
+	    # silently skip everythin else?
+	}
+    }
+
+    return $res;
+}
+
+1;
-- 
2.11.0




More information about the pve-devel mailing list