[pve-devel] [PATCH 1/5] add qemu_img_convert

[Alexandre Derumier]

also work with snapshot as source for qcow2,rbd,sheepdog.

Signed-off-by: Alexandre Derumier <aderumier at odiso.com>
---
 PVE/QemuServer.pm |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/PVE/QemuServer.pm b/PVE/QemuServer.pm
index fb672eb..b55a68e 100644
--- a/PVE/QemuServer.pm
+++ b/PVE/QemuServer.pm
@@ -4478,4 +4478,55 @@ sub is_template {
     return 2 if $baseimagecount < $totalvolumecount; #semi-template
 }
 
+sub qemu_img_convert {
+    my ($src_volid, $dst_volid, $snapname) = @_;
+
+    my $storecfg = PVE::Storage::config();
+    my ($src_storeid, $src_volname) = PVE::Storage::parse_volume_id($src_volid, 1);
+    my ($dst_storeid, $dst_volname) = PVE::Storage::parse_volume_id($dst_volid, 1);
+
+    if ($src_storeid && $dst_storeid) {
+	my $src_scfg = PVE::Storage::storage_config($storecfg, $src_storeid);
+	my $dst_scfg = PVE::Storage::storage_config($storecfg, $dst_storeid);
+
+	my $src_format = qemu_img_format($src_scfg, $src_volname);
+	my $dst_format = qemu_img_format($dst_scfg, $dst_volname);
+
+	my $src_path = PVE::Storage::path($storecfg, $src_volid, $snapname);
+	my $dst_path = PVE::Storage::path($storecfg, $dst_volid);
+
+	my $cmd = [];
+	push @$cmd, '/usr/bin/qemu-img', 'convert', '-t', 'writeback', '-p', '-C';
+	push @$cmd, '-s', $snapname if($snapname && $src_format eq "qcow2");
+	push @$cmd, '-f', $src_format, '-O', $dst_format, $src_path, $dst_path;
+
+	my $parser = sub {
+	    my $line = shift;
+	    print $line."\n";
+	};
+
+	eval  { run_command($cmd, timeout => undef, errfunc => sub {}, outfunc => $parser); };
+	my $err = $@;
+	die "copy failed: $err" if $err;
+    }
+}
+
+sub qemu_img_format {
+    my ($scfg, $volname) = @_;
+
+    if ($scfg->{path} && $volname =~ m/\.(raw|qcow2|qed|vmdk)$/){
+	return $1;
+    }
+    elsif ($scfg->{type} eq 'nexenta' || $scfg->{type} eq 'iscsidirect'){
+	return "iscsi";
+    }
+    elsif ($scfg->{type} eq 'lvm' || $scfg->{type} eq 'iscsi'){
+	return "host_device";
+    }
+    #sheepdog,rbd,or other qemu block driver
+    else{
+	return $scfg->{type};
+    }
+}
+
 1;
-- 
1.7.10.4